What's wrong with my shader? :'(

[EclipsE]

The model doesn't show... And as you see I edited the basic effect from the HM tutorial...

Code:

float4x4 World;
float4x4 View;
float4x4 Project;
sampler TextureSampler;

float3 EyePosition;

bool UseDiffuse;
float4 diffuseColor;

bool UseAmbient;
float4 ambientColor;

bool UseLight;
float3 lightPosition;
float4 lightColor;

bool UseSpecular;
float specularPower;
float4 specularColor;

struct VS_INPUT {
    float4 Position : POSITION0;
    float2 Texcoord : TEXCOORD0;
    float3 Normal : NORMAL0;
};

struct VS_OUTPUT {
    float4 Position : POSITION0;
    float2 Texcoord : TEXCOORD0;
    float3 Normal : TEXCOORD1;
    float3 ViewDirection : TEXCOORD2;
    float3 LightDirection : TEXCOORD3;
};

VS_OUTPUT Process(VS_INPUT Input) {
    VS_OUTPUT Output;

    Output.Position = mul(Input.Position, World * View * Project);
    Output.Texcoord = Input.Texcoord;
    Output.Normal = mul(Input.Normal, World);
    Output.ViewDirection = EyePosition - Output.Position;
    Output.LightDirection = lightPosition - Output.Position;
    return Output;
}

struct PS_INPUT {
    float2 Texcoord : TEXCOORD0;
    float3 Normal : TEXCOORD1;
    float3 ViewDirection : TEXCOORD2;
    float3 LightDirection : TEXCOORD3;
};

float4 Material(PS_INPUT Input) : COLOR0 {
    float3 Normal = normalize(Input.Normal);
    float3 ViewDirection = normalize(Input.ViewDirection);
    float3 LightDirection = normalize(Input.LightDirection);

    float EdgeComponent = dot(Normal, ViewDirection);
   
    float4 TotalAmbient;
    if (UseAmbient)
        TotalAmbient = saturate(ambientColor * EdgeComponent);
    else
        TotalAmbient = (0.0f, 0.0f, 0.0f, 1.0f);

float NDotL = dot(Normal, LightDirection);
float4 DiffuseAverage;
float4 TotalDiffuse;

    if (UseLight)   
    {
        if (UseDiffuse)
        {
        DiffuseAverage = (diffuseColor * lightColor) * 0.5f;
        TotalDiffuse = saturate(DiffuseAverage * NDotL);
        }
        else
        {
        DiffuseAverage = lightColor * 0.5f;
        TotalDiffuse = saturate(DiffuseAverage * NDotL);
        }
    }
    else
    {
        if (UseDiffuse)
        {
            TotalDiffuse = diffuseColor * 0.5f;
        }
        else
        {
            TotalDiffuse = (0.0f, 0.0f, 0.0f, 1.0f);
        }
    }
   
    float4 TextureColor = tex2D(TextureSampler, Input.Texcoord);
    float4 TotalSpecular;
   
    if (UseSpecular)
    {
        float3 Reflection = normalize(2.0f * NDotL * Normal - LightDirection);
        float RDotV = max(0.0f, dot(Reflection, ViewDirection));
        TotalSpecular = saturate(specularColor * pow(RDotV, specularPower));
    }
    else
    {
        TotalSpecular = (0.0f, 0.0f, 0.0f, 1.0f);
    }
   
    if (TextureColor.a == 0.0f) TextureColor.a = 1.0f;
   
    float4 FinalColor = saturate(TotalAmbient + TotalDiffuse + TextureColor + TotalSpecular);
    return FinalColor;
};

technique ProcessMaterial {
    pass P0 {
        VertexShader = compile vs_2_0 Process();
        PixelShader  = compile ps_2_0 Material();
    }
}

[Nemo Krad]

How are you passing the World, View and Projection parameters?

[EclipsE]

They're all ok, I'm passing them in my shader class. I know they're ok because I can render models with the transform texture shader in the tutorial 3. Of course, i changed the shader to pass world, view and projection separate.

Code:

if (shader.Parameters["World"] != null)
            {
                Matrix world = Matrix.CreateScale(Object.Scaling) *
                    Matrix.CreateFromQuaternion(Object.Rotation) *
                    Matrix.CreateTranslation(Object.Position);

                shader.Parameters["World"].SetValue(world);
            }

etc...

[Nemo Krad]

When you say your model does not show at all, do you mean there is nothing there or that you just get a black blob for the model?

[EclipsE]

I don't see it at all...

[Nemo Krad]

You had a few issues there, I have altered the Vertex shader to get it to work. I commented out the bits that upset the rendering of the models.

Code:

VS_OUTPUT Process(VS_INPUT Input) {
    VS_OUTPUT Output;

    //Output.Position = mul(Input.Position, World * View * Projection);   
    Output.Position = mul(Input.Position,mul(mul(World, View), Projection));
    Output.Texcoord = Input.Texcoord;
    Output.Normal = mul(Input.Normal, World);
    //Output.ViewDirection = EyePosition - Output.Position;
    Output.ViewDirection = EyePosition - mul(Input.Position, World);   
    //Output.LightDirection = lightPosition - Output.Position;
    Output.LightDirection = lightPosition - mul(Input.Position, World);
   
    return Output;
}

Also you declare Projection as Project, don't know if this was intensional or not, but my engine uses Projection for this parameter so altered it in the above fix.

Hope this helps

[EclipsE]

Now it works! You deserve a million thank yous!

 

I'm so happy!